; ======================================================================
;
;          Structure and Interpretation of Computer Programs
;                  (trial answer to excercises)
;
;                  计算机程序的构造和解释(习题试解)
;
;                                             created: code17 03/05/05
;                                             modified:
; (保持内容完整不变前提下，可以任意转载)
; ======================================================================

;; SICP No.1.32

;; 递归版本
(define (accumulate-r combiner null-value term a next b)
  (if (> a b)
      null-value
      (combiner (term a)
                (accumulate-r combiner null-value term (next a) next b))))

;; 迭代版本
(define (accumulate-i combiner null-value term a next b)
  (if (> a b)
      null-value
      (accumulate-i combiner
                    (combiner null-value (term a))
                    term (next a) next b)))

;; sum
(define (sum term a next b)
  (accumulate-r + 0 term a next b))

;; product
(define (product term a next b)
  (accumulate-i * 1 term a next b))


;; Test-it:
;; Welcome to MzScheme version 209, Copyright (c) 2004 PLT Scheme, Inc.
;;
;; ;; 我们已经用基于accumulate-i的product代替的原来的product
;; ;; factorial调用了product, 所得结果与以前一致
;; > (factorial 5)
;; 120
;;
;; ;; 我们已经用基于accumulate-r的sum代替的原来的sum
;; ;; integral调用了sum, 所得结果与以前一致
;; > (integral cube 0 1 0.01)
;; 0.24998750000000042


;; BTW, 我们甚至可以定义更高阶的函数，把比较函数也抽象出来
(define (accumulate-high compare combiner null-value term a next b)
  (if (compare a b)
      null-value
      (accumulate-high compare combiner
                       (combiner null-value (term a))
                       term (next a) next b)))